# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit flag-o-matic eutils mercurial

DESCRIPTION="Audacious Player - Your music, your way, no exceptions"
HOMEPAGE="http://audacious-media-player.org/"
SRC_URI="mirror://gentoo/gentoo_ice-xmms-0.2.tar.bz2"

EHG_REPO_URI="http://hg.atheme-project.org/audacious"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha amd64 ~hppa ~mips ~ppc ~ppc64 ~sparc x86"
IUSE="dbus nls"

S="${WORKDIR}/${PN}"

RDEPEND=">=x11-libs/gtk+-2.6
	>=gnome-base/libglade-2.3.1
	dev-libs/libmcs
	dev-libs/libxml2
	media-libs/libsamplerate
	dev-libs/libmowgli
	dbus? ( dev-libs/dbus-glib )"

DEPEND="${RDEPEND}
	nls? ( dev-util/intltool )
	>=dev-util/pkgconfig-0.9.0"

PDEPEND="media-plugins/audacious-plugins"

src_unpack() {
	unpack ${A}

	if [ -n "$NOFETCH" ]; then
		EHG_PULL_CMD=/bin/true
		EHG_CLONE_CMD=/bin/true
	fi

	mercurial_src_unpack
	cp -a "${EHG_STORE_DIR}/${PN}/${PN}"/.hg "${S}" || die

	cd "${S}"

	./autogen.sh || die
}

src_compile() {
	# Bug #42893
	replace-flags "-Os" "-O2"
	# Bug #86689
	is-flag "-O*" || append-flags -O

	econf \
		--enable-mcs \
		--enable-samplerate \
		--enable-chardet \
		$(use_enable dbus) \
		$(use_enable nls) \
		|| die

	emake || die "make failed"
}

src_install() {
	make DESTDIR="${D}" install || die
	dodoc AUTHORS NEWS README

	# Gentoo_ice skin installation; bug #109772
	insinto /usr/share/audacious/Skins/gentoo_ice
	doins "${WORKDIR}"/gentoo_ice/*
	docinto gentoo_ice
	dodoc "${WORKDIR}"/README
}